Een hyperlink maken aan het einde van de exportmacrobewerking

Out of category
1

Hallo

Is het mogelijk om het adres van de exportdirectory als hyperlink in een gebruikersformulier van een VBA-macro te hebben.

Ik wil mijn PDF DXF STEP ZIP export macro gebruiken, ... en dat ik aan het einde van de operatie, naast het bericht "bewerking succesvol voltooid", ofwel een hypertekstlink naar deze map wil hebben, of een knop om er toegang toe te krijgen.

Het ultieme zou zelfs zijn om een knop "Verzenden per e-mail" te hebben die een nieuw bericht met een vooraf gedefinieerd onderwerp en inhoud zou openen en het geëxporteerde document eraan zou toevoegen. Het is voor mijn verzoeken die vrij vaak naar voren komen. Dank u voor uw hulp.

2

Dit kan u een aanwijzing geven door internet explorer te vervangen door windows verkenner:

https://forum.solidworks.com/thread/207477

 

3

Ik heb het gedaan.

Ik eindigde met het maken van een UserForm en de macro vervangt een tekstveld door de bestandsnaam of directory adres. Ik gebruikte de _Click instellingen van het gebruikersformulier om te openen in hyperlinkstijl (ik heb een wijziging aangebracht in de muisopmaak door de "hoofd"-stijl) wanneer ik met de muis over het tekstveld ging, en ik plaatste een knop om toegang te krijgen tot de directory: 

Private Sub LabelFileExport_Click()
On Error GoTo OuvertureFichierErreur
   Dim MonApplication As Object
   Dim MonFichier As String
   Set MonApplication = CreateObject("Shell.Application")
   
   MonFichier = vDestinationPath & "\" & sRefName & ".zip"
   MonApplication.Open (MonFichier)
   
   Set MonApplication = Nothing
Exit Sub

OuvertureFichierErreur:
   Set MonApplication = Nothing
    MsgBox "Erreur lors de l'ouverture de fichier..."

End Sub

Private Sub CommandButtonOpenPath_Click()
Shell Environ("WINDIR") & "\explorer.exe " & vDestinationPath, vbNormalFocus
End Sub

 

Voor het sturen van een e-mail met de bijlage, vond ik een reactie in stukjes op verschillende forums en het ziet er als volgt uit:

Private Sub CommandButtonSendMail_Click()
On Error GoTo EnvoyerEmailErreur
'définition des variables
Dim oOutlook As Outlook.Application
Dim oMailItem As Outlook.MailItem
Dim Body As Variant
Dim sTmp As String, SigString As String
Dim Signature As String
Dim strbody As String

PieceJointe = vDestinationPath & "\" & sRefName & ".zip"

    'préparer Outlook
    PreparerOutlook oOutlook
    Set oMailItem = oOutlook.CreateItem(0)
    
    strbody = "<font size=3>" _
            & "Bonjour,<br>" _
            & "Pouvez-vous s'il vous plaît me faire votre meilleure offre de prix et délais pour la fourniture de l'élément en plan ci-joint.<br>" _
            & "Cordialement,"
    
    'création de l'email
    With oMailItem
        .Display   '<- affiche l'email (si vous ne voulez pas l'afficher, mettez cette ligne en commentaire)
        .Subject = "Demande de prix - " & sRefName
        .HTMLBody = strbody & .HTMLBody
        If PieceJointe <> "" Then .Attachments.Add PieceJointe
       '.Save      '<- sauvegarde l'email avant l'envoi (pour ne pas le sauvegarder, mettez cette ligne en commentaire)
       '.Send      '<- envoie l'email (si vous voulez seulement préparer l'email et l'envoyer manuellement, mettez cette ligne en commentaire)
    End With
    
   'nettoyage...
    If (Not (oMailItem Is Nothing)) Then Set oMailItem = Nothing
    If (Not (oOutlook Is Nothing)) Then Set oOutlook = Nothing

   Exit Sub

EnvoyerEmailErreur:
    If (Not (oMailItem Is Nothing)) Then Set oMailItem = Nothing
    If (Not (oOutlook Is Nothing)) Then Set oOutlook = Nothing
    MsgBox "Le mail n'a pas pu être envoyé...", vbCritical, "Erreur"
End Sub

Private Sub PreparerOutlook(ByRef oOutlook As Object)
'Ce code vérifie si Outlook est prêt à envoyer des emails... Et s'il ne l'est pas, il le prépare.
On Error Resume Next
    'vérification si Outlook est ouvert
    Set oOutlook = GetObject(, "Outlook.Application")
    If (Err.Number <> 0) Then 'si Outlook n'est pas ouvert, une instance est ouverte
        Err.Clear
        Set oOutlook = CreateObject("Outlook.Application")
        
        If (Err.Number <> 0) Then
            MsgBox "Une erreur est survenue lors de l'ouverture de Outlook..."
            Exit Sub
        Else
        End If
    Else    'si Outlook est ouvert, l'instance existante est utilisée
    End If

End Sub