Indicer une table des revisions en automatique

2D plans
1

bonjour

j'ai dossier de 220 mises en plan sur lesquels il y a une table des révisions

je souhaiterai traiter tout les plans en une seule fois pour mettre un indice supérieur et ajouter une mention (ex : MAJ FOND DE PLAN)

est-ce possible via des outils comme Intégration?

précision : je n'ai pas PDM.

merci ! Patrik

2

Comment est réalisé ta table de révision?

C'est une propriété Indice qui évolue?

Propriété stocké dans la MEP ou dans la pièce?

Si oui pas besoin d'intégration si les tables sont toutes existant.

Avec batchproperties tu fais évoluer ta propriété sur le lot de MEP.

Sinon Intégration est capable d'insérer une table de révision sur un lot de plan, et de faire évoluer une propriété en créant une règle.

Suivant comment est créer ta table d'indiçage (sans PDM) la solution n'est pas forcément la même.

3

c'est le deuxième cas, et la table de révision est déjà sur la MEP (pas besoin de l'intégrer)

dans intégration, on a bien une reconnaissance de type : si c'est un plan et qu'il y a une table (de révision)

par contre pas d'action qui pourrait s'associer, comme : rajouter une ligne à ce tableau 

 

 

4

Effectivement je ne vois pas non plus comment ajouter une ligne de révision dans Intégration.

Du côté macro j'ai ça qui fait le job, mais à modifié suivant tes propres propriétés. (Quel nom pour la rev et pour la description.

Actuellement pour la description il y a une input box qui poste la question mais possibilité de mettre un texte en dur assez simplement.

Ensuite il suffit dans Intégration de lancer la macro et cela fait le job en lot.

Code:

'This macro automates the adding of revision information to a drawing document

'Precondition: Any open solidworks drawing document

'Postcondition: A revision line added to the revision table and the revision custom _
                property of the document and all part/assembly files with the same _
                drawing number incremented by one.

Dim swApp As SldWorks.SldWorks
Dim swModel As SldWorks.ModelDoc2
Dim swDrwDoc As SldWorks.DrawingDoc
Dim swRevTable As SldWorks.RevisionTableAnnotation
Dim swView As SldWorks.View
Dim swRefModel As SldWorks.ModelDoc2

Dim revTableTemp As String
Dim Rev As String
Dim revDesc As String
Dim drwNo As String

Sub main()

Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc

'Verify active document is a drawing
If swModel Is Nothing Then
    swApp.SendMsgToUser2 "Please open a .slddrw document and try again!", swMbWarning, swMbOk
    End
ElseIf swModel.GetType <> swDocDRAWING Then
    swApp.SendMsgToUser2 "This macro only works with .slddrw documents!", swMbWarning, swMbOk
    End
End If

Set swDrwDoc = swModel
Set swRevTable = swDrwDoc.GetCurrentSheet.RevisionTable
revTableTemp = swApp.GetUserPreferenceStringValue(swUserPreferenceStringValue_e.swFileLocationsRevisionTableTemplates)

'Set the revision description for the revision to be added
revDesc = InputBox("Enter revision description:", "Add Revision")
'verify the cancel button was not pressed
If revDesc = "" Then
    End
End If

'add revision table if one doesn't exist and set the revision string
If swRevTable Is Nothing Then
    Set swRevTable = swDrwDoc.GetCurrentSheet.InsertRevisionTable(True, 0, 0, swBOMConfigurationAnchor_BottomRight, revTableTemp & "\standard revision block.sldrevtbt")
    Rev = swModel.CustomInfo("Revision") + 1
ElseIf swRevTable.CurrentRevision = "" Then
    Rev = swModel.CustomInfo("Revision") + 1
Else
    'Rev = swRevTable.Text(0, 0) + 1
    'Rev = A
End If

'add revision & description to the revision table
swRevTable.AddRevision Rev
swRevTable.Text(0, 2) = revDesc

'if new revision is less 10, append 0 to beginning
If Rev < 10 Then Rev = "0" & Rev

'bump the revision of model if part/assembly no. is the same as the drawing no.
drwNo = Left(swModel.GetPathName, Len(swModel.GetPathName) - 7)
drwNo = Replace(drwNo, "C:\PDMWorks Local\", "")
Set swView = swModel.GetFirstView
Set swView = swView.GetNextView
Do
    'Debug.Print swView.Name
    Set swRefModel = swView.ReferencedDocument
    If InStr(1, swRefModel.GetPathName, drwNo) Then swRefModel.CustomInfo("Revision") = Rev
    If swRefModel.GetType = swDocASSEMBLY Then
        Dim swComps() As SldWorks.Component2
        Dim swComp As Variant
        Dim swComponent As SldWorks.ModelDoc2
        swComps = swRefModel.GetComponents(True)
        For Each swComp In swComps
            Set swComponent = swComp.GetModelDoc2
            If InStr(1, swComp.GetPathName, drwNo) Then swComponent.CustomInfo("Revision") = Rev
        Next
    End If
    Set swView = swView.GetNextView
Loop Until swView Is Nothing

'set Revision custom property of document and reduce the revision table to the last 3 revisions
swModel.CustomInfo("Revision") = Rev
If swRevTable.RowCount > 4 Then
    Rev = Rev - 3
    Do
        swRevTable.DeleteRevision Rev, True
        Rev = Rev - 1
    Loop Until swRevTable.RowCount = 4
End If
swModel.EditRebuild3

End Sub

 

1 « J'aime »
5

Bonjour;

Pour faire ce type de traitement j'utilise "Intégration" Associé à une petite Macro.
-> il vous faudra la modifier avec :
l'emplacement exact de votre table d'annotaion: pour la commande:
Set mytablerev = currentsheet.InsertRevisionTable(True, 0, 0, 3, "W:\Modeles_solidworks\table_de_revision\VOTRE TABLE DE REVISION.sldrevtbt")


Eventuellement le Nom du calque sur lequel vous voudrez votre Table:
myRevisionTable.GetAnnotation.Layer = "Annotation"


Et surtout le mot clé réglé dans vos paramètres Solidworks pour les nouvelles Revision (Révision ?)...(Option du Systeme...mise en plan...propriété personnalisée utilisée comme révision...
Valeur = swModel.DeleteCustomInfo("Revision")
Valeur = swModel.AddCustomInfo3("", "Revision", swCustomInfoText, Revis)

Voici la macro en question:

Public swApp As SldWorks.SldWorks
Public swDoc As SldWorks.ModelDoc2
Public SwSheet As SldWorks.DrawingDoc
Public swview As SldWorks.View
Public SwTableRev As TableAnnotation
Public swAnn As SldWorks.Annotation

Public currentsheet As Object
Public mytablerev As Object


Dim LayerMgr As SldWorks.LayerMgr
Dim draw As SldWorks.ModelDoc2


Sub Ajout_table_rev()
Set swApp = Application.SldWorks
Set swDoc = swApp.ActiveDoc
Set SwSheet = swDoc

'insertion table
'attention changer le chemin pour la table de revision
' si true alors la table se met sur le point d'ancrage sinon sur coordonné 0,0

Set currentsheet = SwSheet.GetCurrentSheet
Set mytablerev = currentsheet.InsertRevisionTable(True, 0, 0, 3, _
 "W:\Modeles_solidworks\table_de_revision\VOTRE TABLE DE REVISION.sldrevtbt") 'A Modifier
Set myRevisionTable = currentsheet.RevisionTable
longstatus = myRevisionTable.AddRevision("")

'Deplace la table sur le calque "Annotation"
myRevisionTable.GetAnnotation.Layer = "Annotation" 'A Modifier si besoin

Dim Revis As String
Revis = myRevisionTable.CurrentRevision

'Ajoute la valeur de "revision" sur la table
Dim Valeur As String
Set swModel = swApp.ActiveDoc
Valeur = swModel.DeleteCustomInfo("Revision") 'A Modifier si besoin
Valeur = swModel.AddCustomInfo3("", "Revision", swCustomInfoText, Revis) 'A Modifier si besoin

'force la reconstruction
Dim bRet As String
bRet = swModel.Rebuild(swRebuildOptions_e.swForceRebuildAll)

End Sub


Ensuite, après avoir reglé "Intergration" avec les informations "Textes" a votre convenance...., ajouter l'opération "Lancement d'une macro"...
(methode : Insert_table_revision1.Ajout_table_rev)

Cordialement.

1 « J'aime »