Ballontekst koppelen aan de door VBA opgegeven tabel

2D plans
1

Hallo 

Ik zou graag in staat zijn om in mijn configuratieselectiemacro het feit te integreren dat ik de optie "Koppel de ballontekst aan de opgegeven tabel" aanvinkt

Kunt u mij de bestelling in VBA vertellen?

Bedankt


capture-coche.jpg
2

Hallo. De opdracht is SetKeepLinkedToBOM

Voorbeeld:

Option Explicit
Sub main()
Dim swApp As SldWorks.SldWorks
Dim swBOMtbl As SldWorks.BomFeature
Dim swView As SldWorks.View
Dim swModel As SldWorks.ModelDoc2
Dim swSelMgr As SldWorks.SelectionMgr
Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc
Set swSelMgr = swModel.SelectionManager
Dim i As Long
For i = 1 To swSelMgr.GetSelectedObjectCount2(-1)
    If swSelMgr.GetSelectedObjectType3(i, -1) = swSelDRAWINGVIEWS Then
        Set swView = swSelMgr.GetSelectedObject6(i, -1)
    ElseIf swSelMgr.GetSelectedObjectType3(i, -1) = swSelBOMFEATURES Then
        Set swBOMtbl = swSelMgr.GetSelectedObject6(i, -1)
    End If
Next i
If swView Is Nothing Or swBOMtbl Is Nothing Then
    MsgBox "Sélectionner une vue et une table dans l'arbre"
    Exit Sub
End If
MsgBox "Lier la vue: " & swView.Name & vbCr & "à la table: " & swBOMtbl.Name & vbCr & swView.SetKeepLinkedToBOM(True, swBOMtbl.Name)
End Sub

 

1 like
3

Dank u voor uw antwoord,

Dat ga ik zo snel mogelijk testen.