Rysowanie okręgu zaznaczenia makr

Out of category
1

Chciałbym utworzyć makro do zmiany koloru okręgu na rysunku Solidworks.

Chciałbym uruchomić makro wybierz średnicę do wyszukania na przykład: 5   , a następnie w widoku, który bym wybrał , wyszukuje wszystkie średnice i wybiera je, aby następnie móc zmienić kolor.  

Czy jest to możliwe? Jeśli tak, to jak znaleźć okręgi i zaznaczenie?


capture.png
2

Myślę, że ten samouczek odpowiada Twojej prośbie:

https://www.codestack.net/solidworks-api/document/selection/drawing-view-entities/

Dla twojej informacji, ta strona, którą właśnie odkryłem, jest pełna ładnych makr. Jest to bardzo przydatne w mojej nauce makr.

1 polubienie
3

Ten samouczek pozwala wybrać pojedynczy okrąg, ale mam ich o wiele więcej. A zmiana nazwy każdej krawędzi każdego okręgu w pokoju, aby makro działało, jest znacznie dłuższa niż bezpośrednie zaznaczanie okręgów na rysunku. Pomysł był dobry, ale dla mnie nie działa. 

4

Witaj, spróbuj tego z wybranym widokiem:

Spowoduje to, że kółka zmienią kolor na czerwony.

Jeśli chcesz tylko zaznaczyć okręgi: wymaż ostatnie 2 linie 

Option Explicit
Dim swApp As SldWorks.SldWorks
Dim swModel As SldWorks.ModelDoc2
Dim swDraw As SldWorks.DrawingDoc
Dim swView As SldWorks.View
Dim Comp As SldWorks.Component2
Dim vComps As Variant
Dim vComp As Variant
Dim vEdges As Variant
Dim vEdge As Variant
Dim swEdge As SldWorks.Edge
Dim swCurve As SldWorks.Curve
Dim swEntity As SldWorks.Entity
Dim CurveParam As Variant
Dim IsClosed As Boolean
Dim Diameter As Double
Dim boolstatus As Boolean

Sub main()
Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc
Set swDraw = swModel
Set swView = swDraw.ActiveDrawingView
swModel.ClearSelection2 True
vComps = swView.GetVisibleComponents
Diameter = InputBox("Entrer le diamètre en mm")
For Each vComp In vComps
    Set Comp = vComp
    vEdges = swView.GetVisibleEntities(Comp, swViewEntityType_e.swViewEntityType_Edge)
    For Each vEdge In vEdges
        Set swEdge = vEdge
        Set swCurve = swEdge.GetCurve
        If swCurve.IsCircle Then
            swCurve.GetEndParams Empty, Empty, IsClosed, Empty
            If IsClosed Then
                CurveParam = swCurve.CircleParams
                If Abs(Diameter - CurveParam(6) * 2 * 1000) < 0.0001 Then
                    Set swEntity = swEdge
                    swEntity.Select4 True, Nothing
                End If
            End If
        End If
    Next
Next
swModel.SetLineColor 255
swModel.ClearSelection2 True
End Sub

 

3 polubienia
5

To jest dokładnie to, czego potrzebowałem, dziękuję :)