Bonjour à tous,
Je vous explique ma situation. Je travaille sur des assemblages de plusieurs centaines de pièces et je dois exporter certains plans de pièces en PDF. Pour cela, j'insère une table de nomenclature dans mon assemblage. La dernière colonne de la table me dit si on veut le plan de la pièce ou non. Par la suite j'exporte les plans qui m’intéresse en PDF un par un.
Je souhaiterais faire un programme qui automatise un peu tout ça pour me faire gagner du temps. Je voudrais que l'utilisateur rentre le numéro de la pièce dans une boite de dialogue (par exemple "25" pour sélectionner la 25eme pièce de la table). Ensuite, le programme ouvrirait le plan associé à la pièce sélectionnée et l'enregistrerais en PDF.
La deuxième partie du programme ne me pose pas de problème, mais la partie sélection de la pièce par son numéro de nomenclature me pose une colle. Je n'arrive pas à faire un programme capable de lire et trouver la 25eme pièce de la table de nomenclature et d’ouvrir le plan de cette pièce. Si vous avez des idées, ça m'aiderait beaucoup.
En espérant être assez claire :)
Merci pour votre aide
Bonjour;
Voici un exemple pour compter les lignes :
http://help.solidworks.com/2020/English/api/sldworksapi/Get_Components_in_Each_BOM_Table_Row_VB.htm?verRedirect=1
La variable qui devrait vous intéresser est : nNumRow = swTableAnn.RowCount
Une autre Macro pour ouvrir un plan directement depuis une Nomenclature:
https://r1132100503382-eu1-3dswym.3dexperience.3ds.com/#community:yUw32GbYTEqKdgY7-jbZPg/post:YxLaeuf8RRWPjMc6PF9ulA
' ###################################################
' # Title: Open Drawing From BOM #
' # Version: 21.9.6 #
' # Author: Stefan Sterk #
' # Company: Idee Techniek Engineering B.V. #
' # #
' # This macro will try to open the drawing for the #
' # selected component(s) in the Bill of Meterials. #
' # #
' # NOTE: Drawing file must be in same folder as #
' # component and must have the same filename #
' ###################################################
Option Explicit
Dim swApp As SldWorks.SldWorks
Sub main()
Dim swModel As SldWorks.ModelDoc2
Dim swSelMgr As SldWorks.SelectionMgr
Dim swTblAnn As SldWorks.TableAnnotation
Dim swBOMTbl As SldWorks.BomTableAnnotation
Dim swComp As SldWorks.Component2
Dim i As Integer, selType As Integer
Dim frtRow As Long, lstRow As Long
Dim frtCol As Long, lstCol As Long
Dim Row As Integer
Dim vComps As Variant
Dim CfgName As String
Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc
If swModel Is Nothing Then Exit Sub
If Not swModel.GetType = swDocDRAWING Then Exit Sub
Set swSelMgr = swModel.SelectionManager
For i = 1 To swSelMgr.GetSelectedObjectCount2(-1)
selType = swSelMgr.GetSelectedObjectType3(i, -1)
If selType <> 98 Then
MsgBox "Please select a cel from BOM!"
Exit Sub
End If
Set swTblAnn = swSelMgr.GetSelectedObject6(i, -1)
Set swBOMTbl = swTblAnn
swTblAnn.GetCellRange frtRow, lstRow, frtCol, lstCol
For Row = frtRow To lstRow
CfgName = swBOMTbl.BomFeature.GetConfigurations(True, True)(0)
vComps = swBOMTbl.GetComponents2(Row, CfgName)
If Not IsEmpty(vComps) Then
Set swComp = swBOMTbl.GetComponents2(Row, CfgName)(0)
openComponentDrawing swComp
End If
Next Row
Next i
End Sub
Private Function openComponentDrawing(swComp As Component2)
Dim compPath As String
compPath = swComp.GetPathName
Dim drwPath As String
drwPath = Left(compPath, InStrRev(compPath, ".") - 1) & ".slddrw"
' Try Open Drawing
Dim swDrw As SldWorks.DrawingDoc
Dim errors As Long, warnings As Long
Set swDrw = swApp.OpenDoc6(drwPath, swDocDRAWING, 0, "", errors, warnings)
If errors <> 0 Then
If errors = 2 Then
Dim partNumber As String
partNumber = Right(drwPath, Len(drwPath) - InStrRev(drwPath, "\"))
partNumber = Left(partNumber, InStrRev(partNumber, ".") - 1)
MsgBox "Couldn't find drawing for following part number: " & partNumber
End If
Else
swApp.ActivateDoc3 drwPath, False, 0, errors
End If
End Function
Cordialement.
2 « J'aime »