VBA - Gebruikersinteractie en stuklijst

PDM
1

Hoi allemaal 

Laat me mijn situatie aan je uitleggen. Ik werk aan samenstellingen van enkele honderden onderdelen en ik moet sommige onderdelenplannen in PDF exporteren. Om dit te doen, plaats ik een BOM-tafel in mijn assemblage. De laatste kolom van de tabel vertelt me of we de plattegrond van de kamer willen of niet. Vervolgens exporteer ik de plannen die me interesseren één voor één in PDF.

Ik zou graag een programma willen maken dat dit alles een beetje automatiseert om me tijd te besparen. Ik wil graag dat de gebruiker het onderdeelnummer invoert in een dialoogvenster (bijv. "25" om het 25e deel van de tabel te selecteren). Vervolgens opent het programma het plan dat aan de geselecteerde kamer is gekoppeld en slaat het op als een PDF. 

Het tweede deel van het programma is voor mij geen probleem, maar de onderdeelselectie van het onderdeel op basis van het nomenclatuurnummer is voor mij een probleem. Ik kan geen programma maken dat in staat is om het 25e deel van de nomenclatuurtabel te lezen en te vinden en het plan van dit deel te openen. Als je ideeën hebt, zou het me veel helpen.

In de hoop duidelijk genoeg te zijn:)

Bedankt voor je hulp

2

Hallo;

Hier is een voorbeeld voor het tellen van de lijnen:
http://help.solidworks.com/2020/English/api/sldworksapi/Get_Components_in_Each_BOM_Table_Row_VB.htm?verRedirect=1

De variabele waarin u geïnteresseerd zou moeten zijn is: nNumRow = swTableAnn. RowCount (Rijentelling)

Nog een macro om een plan rechtstreeks vanuit een nomenclatuur te openen:

https://r1132100503382-eu1-3dswym.3dexperience.3ds.com/#community:yUw32GbYTEqKdgY7-jbZPg/post:YxLaeuf8RRWPjMc6PF9ulA

' ###################################################
' # Title: Open Drawing From BOM                    #
' # Version: 21.9.6                                 #
' # Author: Stefan Sterk                            #
' # Company: Idee Techniek Engineering B.V.         #
' #                                                 #
' # This macro will try to open the drawing for the #
' # selected component(s) in the Bill of Meterials. #
' #                                                 #
' # NOTE: Drawing file must be in same folder as    #
' # component and must have the same filename       #
' ###################################################
 
Option Explicit
 
Dim swApp As SldWorks.SldWorks
 
Sub main()
 
    Dim swModel  As SldWorks.ModelDoc2
    Dim swSelMgr As SldWorks.SelectionMgr
    Dim swTblAnn As SldWorks.TableAnnotation
    Dim swBOMTbl As SldWorks.BomTableAnnotation
    Dim swComp   As SldWorks.Component2
 
    Dim i As Integer, selType  As Integer
    Dim frtRow As Long, lstRow As Long
    Dim frtCol As Long, lstCol As Long
    Dim Row As Integer
 
    Dim vComps   As Variant
    Dim CfgName  As String
 
    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
 
    If swModel Is Nothing Then Exit Sub
    If Not swModel.GetType = swDocDRAWING Then Exit Sub
 
    Set swSelMgr = swModel.SelectionManager
 
    For i = 1 To swSelMgr.GetSelectedObjectCount2(-1)
 
        selType = swSelMgr.GetSelectedObjectType3(i, -1)
 
        If selType <> 98 Then
            MsgBox "Please select a cel from BOM!"
            Exit Sub
        End If
 
        Set swTblAnn = swSelMgr.GetSelectedObject6(i, -1)
        Set swBOMTbl = swTblAnn
 
        swTblAnn.GetCellRange frtRow, lstRow, frtCol, lstCol
 
        For Row = frtRow To lstRow
            CfgName = swBOMTbl.BomFeature.GetConfigurations(True, True)(0)
            vComps = swBOMTbl.GetComponents2(Row, CfgName)
            If Not IsEmpty(vComps) Then
                Set swComp = swBOMTbl.GetComponents2(Row, CfgName)(0)
                openComponentDrawing swComp
            End If
        Next Row
 
    Next i
End Sub
 
Private Function openComponentDrawing(swComp As Component2)
 
    Dim compPath As String
    compPath = swComp.GetPathName
 
    Dim drwPath As String
    drwPath = Left(compPath, InStrRev(compPath, ".") - 1) & ".slddrw"
 
    ' Try Open Drawing
    Dim swDrw As SldWorks.DrawingDoc
    Dim errors As Long, warnings As Long
    Set swDrw = swApp.OpenDoc6(drwPath, swDocDRAWING, 0, "", errors, warnings)
 
    If errors <> 0 Then
        If errors = 2 Then
            Dim partNumber As String
            partNumber = Right(drwPath, Len(drwPath) - InStrRev(drwPath, "\"))
            partNumber = Left(partNumber, InStrRev(partNumber, ".") - 1)
            MsgBox "Couldn't find drawing for following part number: " & partNumber
        End If
    Else
        swApp.ActivateDoc3 drwPath, False, 0, errors
    End If
 
End Function

Vriendelijke groeten.

2 likes