Excel-beveiligingswaarschuwing bij het openen van een tekening

2D plans
1

Hallo.

 

Om interne redenen moeten we een stuk Excel-tabel in onze tekeningen plakken.

Alles verloopt vlot, maar bij het openen van de bestanden krijgen we dit beveiligingsbericht. (zie PC)

 

Is er een manier om dit bericht te omzeilen zodat het niet meer verschijnt omdat het onze automatische conversietaken via EPDM of MYCADTOOL blokkeert.

 

Bij voorbaat dank voor uw verlichting.

 

A. Mendes

 


alerte_secu_excel.png
2

Hallo;

Dit type bericht lijkt veel op Excel-macrowaarschuwingen. Zou er niet wat in je tabel staan om te kopiëren?
Hoe doe je het lijmen? door OLE-objecten of via een simpele knip- en plakwerk?
De nevenvraag is: heb je voorwaardelijke opmaak in je Excel?
Is het niet mogelijk om een algemene tabel te gebruiken in plaats van dit gerapporteerde document?
 

Als je geïnteresseerd bent, heb ik een macro (Solidworks) om Excel-cellen in Europarlementariërs te importeren in de vorm van een nieuwe tabel.
 

Vriendelijke groeten.

 


import_from_excel.swp
1 like
3

Hello@Mclane

Mijn collage wordt gedaan door een simpele copy-paste die automatisch een OLE-object voor mij genereert.

Ja, voorwaardelijke opmaak in de tabel.

Voor de implementatie van een algemene tabel, waarom niet alleen als het per macro wordt gedaan. Dus ik ben uiteindelijk een nemer.

Bedankt voor het onderzoeken van het onderwerp.

A. Mendes

 

 

 

4

A. Mendes;

Ik heb net mijn macro beschikbaar gemaakt op de vorige post.
Hier is de code....
 


' Prerequis: Une Mise en plan Solidworks est ouverte, Un excel est ouvert et la zone à importer est selectionnée.

Option Explicit

Dim swApp                   As SldWorks.SldWorks
Dim swModel                 As SldWorks.ModelDoc2
Dim swDraw                  As SldWorks.DrawingDoc

Sub main()

    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    Set swDraw = swModel
    
    ImportTable swDraw
    
End Sub

Sub ImportTable(drawingSheet As SldWorks.DrawingDoc)

    Dim swTable                 As SldWorks.TableAnnotation
    Dim swAnn                   As SldWorks.Annotation
    Dim nNumCol                 As Long
    Dim nNumRow                 As Long
    Dim sRowStr                 As String
    Dim i                       As Long
    Dim j                       As Long
    
    Dim objExcelObject          As Excel.Application
    Dim objBook1                As Excel.Workbook
    Dim objSheet1               As Excel.Worksheet
    
    Dim iRows                   As Integer
    Dim iCols                   As Integer
    Dim sBase                   As String
    
    MsgBox ("Ouvrez un fichier Excel,et selectionnez les cellules à importer." & Chr(10) & "...." & Chr(10) & "Cliquez sur 'OK' pour debuter l'importation.")
    
    Set objExcelObject = GetObject(, "Excel.Application")
    

    If objExcelObject Is Nothing Then
       MsgBox "Un fichier Excel doit être ouvert." & Chr(10) & "Fin de la macro."
    Else

    iRows = objExcelObject.Selection.Rows.Count
    iCols = objExcelObject.Selection.Columns.Count
    sBase = objExcelObject.Selection.Cells(1, 1).Address

    Dim sWidth As Double
    Dim sHeight As Double
    
    drawingSheet.GetCurrentSheet().GetSize sWidth, sHeight

    Set swTable = drawingSheet.InsertTableAnnotation2(False, 0, sHeight, swBOMConfigurationAnchor_TopLeft, "", iRows, iCols)
    
    
    
    For i = 0 To iRows - 1
        Dim cell As Range
        
        For j = 0 To iCols - 1
            Set cell = objExcelObject.Selection.Range("A1").Offset(i, j)
            
            If i = 0 Then
                ' Definition des largeurs de colonnes
                swTable.SetColumnWidth j, cell.ColumnWidth * 7.5 / 4000, swTableRowColChange_TableSizeCanChange
            End If
            
            ' Definition du format des cellules
            Dim tf As TextFormat
            Set tf = swTable.GetTextFormat
            
            tf.Bold = cell.Font.Bold
            tf.Strikeout = cell.Font.Strikethrough
            tf.Italic = cell.Font.Italic
            If cell.Font.Underline > 0 Then tf.Underline = True
            tf.CharHeightInPts = cell.Font.Size
            
            
            ' Definition du format du texte
            swTable.SetCellTextFormat i, j, False, tf
            
            
            ' Alignement des cellules
            swTable.CellTextHorizontalJustification(i, j) = Switch(cell.HorizontalAlignment = XlHAlign.xlHAlignRight, swTextJustificationRight, cell.HorizontalAlignment = XlHAlign.xlHAlignCenter, swTextJustificationCenter, True, swTextJustificationLeft)
            swTable.CellTextVerticalJustification(i, j) = Switch(cell.VerticalAlignment = XlVAlign.xlVAlignBottom, swTextAlignmentBottom, cell.VerticalAlignment = XlVAlign.xlVAlignCenter, swTextAlignmentMiddle, True, swTextAlignmentTop)
            
            swTable.Text(i, j) = cell
        
        Next j
        ' Definition des Hauteur de colonnes
        swTable.SetRowHeight i, cell.RowHeight / 0.75 / 4000, swTableRowColChange_TableSizeCanChange
        
    Next i
        
    End If
 
    Set objSheet1 = Nothing
    Set objBook1 = Nothing
    Set objExcelObject = Nothing
    
    
End Sub

 

2 likes
5

@Mclane

 

Hartelijk dank. Ik zal proberen het onderwerp zo snel mogelijk te onderzoeken, maar op dit moment ben ik overweldigd door werk.

Mocht je in de tussentijd helaas een oplossing vinden voor de boodschap, dan ben ik altijd geïnteresseerd.