Contenu d'une esquisse

3D Design
1

Bonjour,

Une question de bizuth, y a t il un moyen de lister le contenu d'une esquisse ? J'aimerai savoir combien une esquisse contient d'arcs, de lignes ... Il y a 30 ans sur mon Cadkey favori d'alors ça se faisait en un clic. Là je tourne un peu en rond. 

Je vous joints une petite vidéo Solidworkienne de circonstance

Bonne journée et bon courage

Merci à tous


etiaffage.mp4
1 « J'aime »
2

Bonjour,

Créé une nouvelle macro et insère ce code:

Option Explicit
Sub main()
    Dim swApp As SldWorks.SldWorks
    Dim swModel As SldWorks.ModelDoc2
    Dim swSelMgr As SldWorks.SelectionMgr
    Dim swSketch As SldWorks.Sketch
    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    Set swSketch = swModel.GetActiveSketch2
    If swSketch Is Nothing Then
        Set swSelMgr = swModel.SelectionManager
        If swSelMgr.GetSelectedObjectCount2(-1) = 0 Then Exit Sub
        If swSelMgr.GetSelectedObjectType3(1, -1) <> swSelectType_e.swSelSKETCHES Then Exit Sub
        Dim swFeat As SldWorks.Feature
        Set swFeat = swSelMgr.GetSelectedObject5(1)
        Set swSketch = swFeat.GetSpecificFeature
    End If
    If swSketch Is Nothing Then Exit Sub
    Dim myText As String
    myText = "  Nombre de lignes = " & swSketch.GetLineCount
    myText = myText & vbCrLf & "  Nombre d'arcs = " & swSketch.GetArcCount
    myText = myText & vbCrLf & "  Nombre de points = " & swSketch.GetSketchPointsCount
    myText = myText & vbCrLf & "  Nombre d'éllipses  = " & swSketch.GetEllipseCount
    myText = myText & vbCrLf & "  Nombre de paraboles  = " & swSketch.GetParabolaCount
    MsgBox myText
End Sub

 lance la macro avec une esquisse ouverte ou sélectionnée 

1 « J'aime »
3

Oh oh voilà qui va me déniaiser en API et autre macro. En plus cela m'a l'air bien clair, et puis ça marche

Merci beaucoup

1 « J'aime »