Inhoud van een schets

3D Design
1

Hallo

Een beginnersvraag, is er een manier om de inhoud van een schets op te sommen? Ik zou graag willen weten hoeveel bogen, lijnen ...  30 jaar geleden op mijn favoriete Cadkey destijds, het was met één klik gedaan. Nu draai ik een beetje rondjes. 

Ik voeg voor de gelegenheid een kleine Solidworkian-video toe

Fijne dag en veel succes

Dank u allen


etiaffage.mp4
1 like
2

Hallo

Maak een nieuwe macro en voer deze code in:

Option Explicit
Sub main()
    Dim swApp As SldWorks.SldWorks
    Dim swModel As SldWorks.ModelDoc2
    Dim swSelMgr As SldWorks.SelectionMgr
    Dim swSketch As SldWorks.Sketch
    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    Set swSketch = swModel.GetActiveSketch2
    If swSketch Is Nothing Then
        Set swSelMgr = swModel.SelectionManager
        If swSelMgr.GetSelectedObjectCount2(-1) = 0 Then Exit Sub
        If swSelMgr.GetSelectedObjectType3(1, -1) <> swSelectType_e.swSelSKETCHES Then Exit Sub
        Dim swFeat As SldWorks.Feature
        Set swFeat = swSelMgr.GetSelectedObject5(1)
        Set swSketch = swFeat.GetSpecificFeature
    End If
    If swSketch Is Nothing Then Exit Sub
    Dim myText As String
    myText = "  Nombre de lignes = " & swSketch.GetLineCount
    myText = myText & vbCrLf & "  Nombre d'arcs = " & swSketch.GetArcCount
    myText = myText & vbCrLf & "  Nombre de points = " & swSketch.GetSketchPointsCount
    myText = myText & vbCrLf & "  Nombre d'éllipses  = " & swSketch.GetEllipseCount
    myText = myText & vbCrLf & "  Nombre de paraboles  = " & swSketch.GetParabolaCount
    MsgBox myText
End Sub

 Hiermee start u de macro met een geopende of geselecteerde schets

1 like
3

Oh oh dat gaat me in gevaar brengen in API en andere macro. Trouwens, het lijkt me heel duidelijk, en het werkt

Hartelijk dank

1 like