Conversion PARTS vers STEP en masse

3D Design
1

Tout est dans le titre les amis,

Est ce que quelqu'un aurai un soft ou une Macro (encore mieux) pour convertir plusieurs parts en step de façon massive.

Ou même en passant directement par l'assemble, car de base il n'est possible de faire ça qu'avec l'export en IGES et non STEP.

Je précise que je n'ai pas de maintenance myCADservices donc pas Batchconverter qui je le sais fait ça très bien.

J'espère que j'ai été assez clair dans ma demande.

Merci

2

Bonjour,

Si vous enregistrez vous assemblage en STEP; la personne qui ouvrira votre STEP devra paramétrer dans ses options ou pourvoir l'ouvrir avec des pièces séparés et non une seule si c'est ce que vous chrechez.

3

Bonjour. Essaye ca avec une pièce ou un assemblage ouvert. Cela sauvegardera chaque pièces en fichier step dans le même répertoire.

Option Explicit
Dim lComps As Object
Sub main()
Dim swApp As SldWorks.SldWorks
Dim swModel As SldWorks.ModelDoc2
Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc
If swModel Is Nothing Then
    MsgBox "Ouvrir un assemblage ou une pièce"
    Exit Sub
End If
swApp.SetUserPreferenceIntegerValue swUserPreferenceIntegerValue_e.swStepAP, 214
Select Case swModel.GetType
    Case swDocumentTypes_e.swDocASSEMBLY
        Dim swAssy As SldWorks.AssemblyDoc
        Dim swConf As SldWorks.Configuration
        Dim swRootComp As SldWorks.Component2
        Set swAssy = swModel
        Set swConf = swAssy.GetActiveConfiguration
        Set swRootComp = swConf.GetRootComponent3(True)
        Set lComps = CreateObject("Scripting.Dictionary")
        TraverseComponent swRootComp

    Case swDocumentTypes_e.swDocPART
        Save2Step swModel
        
    Case Else
        MsgBox "Ouvrir un assemblage ou une pièce"
        Exit Sub
End Select
End Sub

Sub TraverseComponent(swComp As SldWorks.Component2)
    Dim vChilds As Variant
    Dim vChild As Variant
    Dim swChildComp As SldWorks.Component2
    Dim swModel As ModelDoc2
    vChilds = swComp.GetChildren
    For Each vChild In vChilds
        Set swChildComp = vChild
        Set swModel = swChildComp.GetModelDoc2
        If swModel.GetType = swDocumentTypes_e.swDocASSEMBLY Then
            TraverseComponent swChildComp
        Else
            If Not lComps.Exists(swModel.GetPathName) Then
                lComps.Add swModel.GetPathName, Empty
                Save2Step swModel
            End If
        End If
    Next
End Sub

Private Sub Save2Step(swModel As SldWorks.ModelDoc2)
    Dim FilePath As String
    FilePath = Left(swModel.GetPathName, InStrRev(swModel.GetPathName, ".") - 1) & ".STEP"
    swModel.Extension.SaveAs2 FilePath, 0, swSaveAsOptions_e.swSaveAsOptions_Silent, Nothing, Empty, False, Empty, Empty
End Sub

 

2 « J'aime »
4

Merci JeromeP, ça fonctionne et c'est exactement ce que je voulais.