Umrüstung von PARTS auf Kläranlage in großen Mengen

3D Design
1

Es steckt alles im Titel Freunde,

Wird jemand eine Software oder ein Makro (noch besser) haben, um mehrere Teile massiv in einen Schritt umzuwandeln?

Oder sogar, indem man direkt durch die Baugruppe geht, denn im Grunde ist dies nur mit dem Export in IGES und nicht in STEP möglich.

Ich gebe an, dass ich keine myCADservices-Wartung habe, also nicht Batchconverter, von dem ich weiß, dass er das sehr gut macht.

Ich hoffe, ich war in meiner Bitte klar genug.

Vielen Dank

2

Hallo

Wenn Sie Ihre Assembly in STEP; Die Person, die Ihre Kläranlage öffnen wird, muss sie in ihren Optionen einrichten oder in der Lage sein, sie mit einzelnen Teilen und nicht nur mit einem zu öffnen, wenn Sie das möchten.

3

Hallo. Versuchen Sie dies mit einem offenen Teil oder einer offenen Baugruppe. Dadurch wird jedes Teil als Schrittdatei im selben Verzeichnis gespeichert.

Option Explicit
Dim lComps As Object
Sub main()
Dim swApp As SldWorks.SldWorks
Dim swModel As SldWorks.ModelDoc2
Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc
If swModel Is Nothing Then
    MsgBox "Ouvrir un assemblage ou une pièce"
    Exit Sub
End If
swApp.SetUserPreferenceIntegerValue swUserPreferenceIntegerValue_e.swStepAP, 214
Select Case swModel.GetType
    Case swDocumentTypes_e.swDocASSEMBLY
        Dim swAssy As SldWorks.AssemblyDoc
        Dim swConf As SldWorks.Configuration
        Dim swRootComp As SldWorks.Component2
        Set swAssy = swModel
        Set swConf = swAssy.GetActiveConfiguration
        Set swRootComp = swConf.GetRootComponent3(True)
        Set lComps = CreateObject("Scripting.Dictionary")
        TraverseComponent swRootComp

    Case swDocumentTypes_e.swDocPART
        Save2Step swModel
        
    Case Else
        MsgBox "Ouvrir un assemblage ou une pièce"
        Exit Sub
End Select
End Sub

Sub TraverseComponent(swComp As SldWorks.Component2)
    Dim vChilds As Variant
    Dim vChild As Variant
    Dim swChildComp As SldWorks.Component2
    Dim swModel As ModelDoc2
    vChilds = swComp.GetChildren
    For Each vChild In vChilds
        Set swChildComp = vChild
        Set swModel = swChildComp.GetModelDoc2
        If swModel.GetType = swDocumentTypes_e.swDocASSEMBLY Then
            TraverseComponent swChildComp
        Else
            If Not lComps.Exists(swModel.GetPathName) Then
                lComps.Add swModel.GetPathName, Empty
                Save2Step swModel
            End If
        End If
    Next
End Sub

Private Sub Save2Step(swModel As SldWorks.ModelDoc2)
    Dim FilePath As String
    FilePath = Left(swModel.GetPathName, InStrRev(swModel.GetPathName, ".") - 1) & ".STEP"
    swModel.Extension.SaveAs2 FilePath, 0, swSaveAsOptions_e.swSaveAsOptions_Silent, Nothing, Empty, False, Empty, Empty
End Sub

 

2 „Gefällt mir“
4

Danke JeromeP, es funktioniert und es ist genau das, was ich wollte.