SolidWorks Erwartete Funktion oder Variablenfehler

Macro
1

Hallo an alle

Ich habe diesen Fehler: " Kompilierungsfehler: Funktion oder Variable erwartet "

Der Fehler befindet sich in der nächsten Zeile und die Funktion " GetTransparency "

Debug.Print swSketchPicture.GetTransparency(Style, Transparency, MatchingColor, MatchingTolerance)

Ich bin auf SolidWorks 2022 und der Code lautet wie folgt:

Sub recupTranparenceImage()
Dim swApp As SldWorks.SldWorks
Dim swModel As SldWorks.ModelDoc2
Dim swSelMgr As SldWorks.SelectionMgr
Dim swFeat As SldWorks.Feature
Dim swSketchPicture As SldWorks.ISketchPicture
Dim boolstatus As Boolean
'Dim instance As ISketchPicture
Dim Style As Long
Dim Transparency As Double
Dim MatchingColor As Long
Dim MatchingTolerance As Double
 
Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc
'boolstatus = swModel.Extension.SelectByID2("Feuille1", "SHEET", 5.43900806628579E-02, 0.13276815279762, 0, False, 0, Nothing, 0)
swModel.EditTemplate
swModel.EditSketch
boolstatus = swModel.Extension.SelectByID2("Image d'esquisse2", "SKETCHBITMAP", 0.166852606603703, 0.134853758836237, 0, False, 0, Nothing, 0)
Set swSelMgr = swModel.SelectionManager
Set swFeat = swSelMgr.GetSelectedObject6(1, -1)
Set swSketchPicture = swFeat.GetSpecificFeature2
'Debug.Print swSketchPicture.SetTransparency(2, 0.97, 0, 0)

Debug.Print swSketchPicture.GetTransparency(Style, Transparency, MatchingColor, MatchingTolerance)
Debug.Print Transparency
swModel.EditSheet
End Sub

Haben Sie eine Idee, was los ist?

2

Hallo

Versuchen Sie, den Rückgabewert in einen Typ zu konvertieren, der durch einen Druck angezeigt werden kann:

Debug.Print CStr( swSketchPicture.GetTransparency(Style, Transparency, MatchingColor, MatchingTolerance) )
3

Danke @Sylk , aber keine Änderung, ich habe immer noch den gleichen Fehler.

4

Und was ist mit

swSketchPicture.GetTransparency(Style, Transparency, MatchingColor, MatchingTolerance)
Debug.Print Style
Debug.Print Transparency
Debug.Print MatchingColor
Debug.Print MatchingTolerance

Wenn die GetTransparency-Funktion keinen Wert zurückgibt, müssen Sie die Variablen in ihren Argumenten verwenden.

1 „Gefällt mir“
5

Ja danke @Sylk , das ist genau das, was ich gerade getestet habe, dank Ihrer Wertreflexion, die von der Funktion zurückgegeben wird:

Sub recupTranparenceImage()
Dim swApp As SldWorks.SldWorks
Dim swModel As SldWorks.ModelDoc2
Dim swSelMgr As SldWorks.SelectionMgr
Dim swFeat As SldWorks.Feature
Dim swSketchPicture As SldWorks.ISketchPicture
Dim boolstatus As Boolean
Dim Style As Long
Dim Transparency As Double
Dim MatchingColor As Long
Dim MatchingTolerance As Double
 
Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc
swModel.EditTemplate
swModel.EditSketch
boolstatus = swModel.Extension.SelectByID2("Image d'esquisse2", "SKETCHBITMAP", 0.166852606603703, 0.134853758836237, 0, False, 0, Nothing, 0)
Set swSelMgr = swModel.SelectionManager
Set swFeat = swSelMgr.GetSelectedObject6(1, -1)
Set swSketchPicture = swFeat.GetSpecificFeature2

swSketchPicture.GetTransparency Style, Transparency, MatchingColor, MatchingTolerance
Debug.Print Transparency
swModel.EditSheet
End Sub
1 „Gefällt mir“