Ausführen eines Makros für alle Komponenten in einer Baugruppe

3D Design
1

Hallo ihr alle

Ich möchte ein Makro anwenden, das die Einheiten aller Teile einer Baugruppe (oder sogar eines Ordners) ändert, ohne sie einzeln öffnen zu müssen.

Ich habe bereits den Code zum Ändern von Einheiten, aber mir fehlt das Teil, um es auf alle Elemente einer Baugruppe (im Wesentlichen Teile) anzuwenden.

Könnte mir jemand den richtigen Weg weisen?

 


change_unites.swp
2

Sehen Sie sich dieses Makro an, das eine Assembly von einer Seite zur anderen durchquert:

 

 '--------------------------------------------------------------------------
' Preconditions:
' 1. Open an assembly document containing nested subassemblies.
' 2. Open the Immediate window.
'
' Postconditions:
' 1. Traverses the assembly.
' 2. Examine the Immediate window.
'---------------------------------------------------------------------------

Option Explicit

Sub TraverseFeatureFeatures(swFeat As SldWorks.Feature, nLevel As Long)

    Dim swSubFeat                   As SldWorks.Feature
    Dim swSubSubFeat                As SldWorks.Feature
    Dim swSubSubSubFeat             As SldWorks.Feature
    Dim sPadStr                     As String
    Dim i                           As Long

    For i = 0 To nLevel
        sPadStr = sPadStr + "  "
    Next i

    While Not swFeat Is Nothing
        If swFeat.GetTypeName = "Reference" Then
        Debug.Print "0:" + sPadStr + swFeat.Name + " [" + swFeat.GetTypeName + "]"
        End If
        Set swSubFeat = swFeat.GetFirstSubFeature
        While Not swSubFeat Is Nothing
            Debug.Print "1:" + sPadStr + "  " + swSubFeat.Name + " [" + swSubFeat.GetTypeName + "]"

            Set swSubSubFeat = swSubFeat.GetFirstSubFeature
            While Not swSubSubFeat Is Nothing
                Debug.Print "2:" + sPadStr + "    " + swSubSubFeat.Name + " [" + swSubSubFeat.GetTypeName + "]"

                Set swSubSubSubFeat = swSubSubFeat.GetFirstSubFeature
                While Not swSubSubSubFeat Is Nothing
                    Debug.Print "3:" + sPadStr + "      " + swSubSubSubFeat.Name + " [" + swSubSubSubFeat.GetTypeName + "]"

                    Set swSubSubSubFeat = swSubSubSubFeat.GetNextSubFeature()

                Wend

                Set swSubSubFeat = swSubSubFeat.GetNextSubFeature()

            Wend

            Set swSubFeat = swSubFeat.GetNextSubFeature()

        Wend

        Set swFeat = swFeat.GetNextFeature

    Wend

End Sub

Sub TraverseComponentFeatures(swComp As SldWorks.Component2, nLevel As Long)

    Dim swFeat As SldWorks.Feature

    Set swFeat = swComp.FirstFeature
    TraverseFeatureFeatures swFeat, nLevel

End Sub


Sub TraverseComponent(swComp As SldWorks.Component2, nLevel As Long)

    Dim vChildComp                  As Variant
    Dim swChildComp                 As SldWorks.Component2
    Dim sPadStr                     As String
    Dim i                           As Long
    

    For i = 0 To nLevel - 1
        sPadStr = sPadStr + "  "
    Next i

    vChildComp = swComp.GetChildren
    For i = 0 To UBound(vChildComp)
        Set swChildComp = vChildComp(i)

        Debug.Print sPadStr & "+" & swChildComp.Name2 & " <" & swChildComp.ReferencedConfiguration & ">"

        TraverseComponentFeatures swChildComp, nLevel
        TraverseComponent swChildComp, nLevel + 1

    Next i

End Sub

Sub TraverseModelFeatures(swModel As SldWorks.ModelDoc2, nLevel As Long)

    Dim swFeat As SldWorks.Feature

    Set swFeat = swModel.FirstFeature
    TraverseFeatureFeatures swFeat, nLevel

End Sub

Sub main()

    Dim swApp                       As SldWorks.SldWorks
    Dim swModel                     As SldWorks.ModelDoc2
    Dim swConfMgr                   As SldWorks.ConfigurationManager
    Dim swConf                      As SldWorks.Configuration
    Dim swRootComp                  As SldWorks.Component2
    Dim StartTime                   As Double
    Dim FinishTime                  As Double
    Dim TotalTime                   As Double
    

    Set swApp = CreateObject("SldWorks.Application")
    Set swModel = swApp.ActiveDoc
    Set swConfMgr = swModel.ConfigurationManager
    Set swConf = swConfMgr.ActiveConfiguration
    Set swRootComp = swConf.GetRootComponent3(True)

    StartTime = Timer ' Start time

    Debug.Print "File = " & swModel.GetPathName

    TraverseModelFeatures swModel, 1

    If swModel.GetType = SwConst.swDocASSEMBLY Then
        TraverseComponent swRootComp, 1

    End If

    FinishTime = Timer ' End time
    TotalTime = FinishTime - StartTime ' Elapsed time
    Debug.Print ("Time = " & TotalTime & " sec")
    

End Sub

Es zeigt Ihnen den Namen jedes Teils, jeder Baugruppe und sogar jeder Funktion der Hauptbaugruppe.

Dann müssen Sie dank des Namens oder des Pfads nur noch den angeforderten Teil öffnen, Ihren Code anwenden, speichern und schließen.

Ein weiteres Beispiel ist eine Suche mit SOLIDWORKS Makro- und Traversenkomponenten.

EDIT: Und die SW-API-Version:

https://help.solidworks.com/2020/english/api/sldworksapi/Traverse_Assembly_at_Component_and_Feature_Level_Example_VB.htm?verRedirect=1

1 „Gefällt mir“
3

2 Drei weitere lose Beispiele:

https://stackoverflow.com/questions/60000471/saving-all-parts-in-an-assembly-as-step-with-custom-properties-how-to-solve-run

https://r1132100503382-eu1-3dswym.3dexperience.3ds.com/#community:yUw32GbYTEqKdgY7-jbZPg/iquestion:6lAv8HurTReoBjJqUe3xIg

 

4

Hallo

Andernfalls können Sie dies ohne Code mit dem Integrationstool myCADtools  tun:

Hilfe bei der Integration: https://help.visiativ.com/mycadtools/2022/fr/Integration.html

Vorgang zum Starten eines Makros: https://help.visiativ.com/mycadtools/2022/fr/Integration186.html

Sie können myCADtools 30 Tage lang testen, wenn Sie kein myCADservices Premium-Abonnement haben: https://www.lynkoa.com/mycadtools

Schönen Tag 

Philippe