Een macro uitvoeren voor alle onderdelen in een assembly

3D Design
1

Hoi allemaal

Ik zou graag een macro willen toepassen die de eenheden van alle onderdelen van een assemblage (of zelfs een map) wijzigt zonder ze één voor één te hoeven openen.

Ik heb al de code voor het wijzigen van eenheden, maar ik mis het onderdeel om het toe te passen op alle elementen van een assemblage (in wezen onderdelen).

Zou iemand mij in de juiste richting kunnen wijzen?

 


change_unites.swp
2

Kijk eens naar deze macro die een assemblage van de ene naar de andere kant kruist:

 

 '--------------------------------------------------------------------------
' Preconditions:
' 1. Open an assembly document containing nested subassemblies.
' 2. Open the Immediate window.
'
' Postconditions:
' 1. Traverses the assembly.
' 2. Examine the Immediate window.
'---------------------------------------------------------------------------

Option Explicit

Sub TraverseFeatureFeatures(swFeat As SldWorks.Feature, nLevel As Long)

    Dim swSubFeat                   As SldWorks.Feature
    Dim swSubSubFeat                As SldWorks.Feature
    Dim swSubSubSubFeat             As SldWorks.Feature
    Dim sPadStr                     As String
    Dim i                           As Long

    For i = 0 To nLevel
        sPadStr = sPadStr + "  "
    Next i

    While Not swFeat Is Nothing
        If swFeat.GetTypeName = "Reference" Then
        Debug.Print "0:" + sPadStr + swFeat.Name + " [" + swFeat.GetTypeName + "]"
        End If
        Set swSubFeat = swFeat.GetFirstSubFeature
        While Not swSubFeat Is Nothing
            Debug.Print "1:" + sPadStr + "  " + swSubFeat.Name + " [" + swSubFeat.GetTypeName + "]"

            Set swSubSubFeat = swSubFeat.GetFirstSubFeature
            While Not swSubSubFeat Is Nothing
                Debug.Print "2:" + sPadStr + "    " + swSubSubFeat.Name + " [" + swSubSubFeat.GetTypeName + "]"

                Set swSubSubSubFeat = swSubSubFeat.GetFirstSubFeature
                While Not swSubSubSubFeat Is Nothing
                    Debug.Print "3:" + sPadStr + "      " + swSubSubSubFeat.Name + " [" + swSubSubSubFeat.GetTypeName + "]"

                    Set swSubSubSubFeat = swSubSubSubFeat.GetNextSubFeature()

                Wend

                Set swSubSubFeat = swSubSubFeat.GetNextSubFeature()

            Wend

            Set swSubFeat = swSubFeat.GetNextSubFeature()

        Wend

        Set swFeat = swFeat.GetNextFeature

    Wend

End Sub

Sub TraverseComponentFeatures(swComp As SldWorks.Component2, nLevel As Long)

    Dim swFeat As SldWorks.Feature

    Set swFeat = swComp.FirstFeature
    TraverseFeatureFeatures swFeat, nLevel

End Sub


Sub TraverseComponent(swComp As SldWorks.Component2, nLevel As Long)

    Dim vChildComp                  As Variant
    Dim swChildComp                 As SldWorks.Component2
    Dim sPadStr                     As String
    Dim i                           As Long
    

    For i = 0 To nLevel - 1
        sPadStr = sPadStr + "  "
    Next i

    vChildComp = swComp.GetChildren
    For i = 0 To UBound(vChildComp)
        Set swChildComp = vChildComp(i)

        Debug.Print sPadStr & "+" & swChildComp.Name2 & " <" & swChildComp.ReferencedConfiguration & ">"

        TraverseComponentFeatures swChildComp, nLevel
        TraverseComponent swChildComp, nLevel + 1

    Next i

End Sub

Sub TraverseModelFeatures(swModel As SldWorks.ModelDoc2, nLevel As Long)

    Dim swFeat As SldWorks.Feature

    Set swFeat = swModel.FirstFeature
    TraverseFeatureFeatures swFeat, nLevel

End Sub

Sub main()

    Dim swApp                       As SldWorks.SldWorks
    Dim swModel                     As SldWorks.ModelDoc2
    Dim swConfMgr                   As SldWorks.ConfigurationManager
    Dim swConf                      As SldWorks.Configuration
    Dim swRootComp                  As SldWorks.Component2
    Dim StartTime                   As Double
    Dim FinishTime                  As Double
    Dim TotalTime                   As Double
    

    Set swApp = CreateObject("SldWorks.Application")
    Set swModel = swApp.ActiveDoc
    Set swConfMgr = swModel.ConfigurationManager
    Set swConf = swConfMgr.ActiveConfiguration
    Set swRootComp = swConf.GetRootComponent3(True)

    StartTime = Timer ' Start time

    Debug.Print "File = " & swModel.GetPathName

    TraverseModelFeatures swModel, 1

    If swModel.GetType = SwConst.swDocASSEMBLY Then
        TraverseComponent swRootComp, 1

    End If

    FinishTime = Timer ' End time
    TotalTime = FinishTime - StartTime ' Elapsed time
    Debug.Print ("Time = " & TotalTime & " sec")
    

End Sub

Het toont u de naam van elk onderdeel, de assemblage en zelfs de functie van de hoofdassemblage.

Vervolgens hoeft u dankzij de naam of het pad alleen maar het gevraagde onderdeel te openen, uw code toe te passen, op te slaan en te sluiten.

Een ander voorbeeld is een zoekopdracht met solidworks macro- en traverse-componenten.

EDIT: En de SW API-versie:

https://help.solidworks.com/2020/english/api/sldworksapi/Traverse_Assembly_at_Component_and_Feature_Level_Example_VB.htm?verRedirect=1

1 like
3

2 Drie andere losse voorbeelden:

https://stackoverflow.com/questions/60000471/saving-all-parts-in-an-assembly-as-step-with-custom-properties-how-to-solve-run

https://r1132100503382-eu1-3dswym.3dexperience.3ds.com/#community:yUw32GbYTEqKdgY7-jbZPg/iquestion:6lAv8HurTReoBjJqUe3xIg

 

4

Hallo

Anders kunt u het zonder code doen met de integratietool myCADtools :

Hulp bij integratie: https://help.visiativ.com/mycadtools/2022/fr/Integration.html

Bewerking om een macro te starten: https://help.visiativ.com/mycadtools/2022/fr/Integration186.html

U kunt myCADtools 30 dagen testen als u geen myCADservices Premium-abonnement hebt: https://www.lynkoa.com/mycadtools

Fijne dag 

Philippe