Makro zum Ausblenden der Grundkarte, der Stücklistentabelle (nicht der Blase) und der Revisionstabelle

Macro
1

Hallo
Für einen Zeichnungsexport nur mit Ansichten suche ich nach einem Makro, das:
1 - blendet die Grundkarte aus (deaktivieren Sie " Grundkarte anzeigen " in der Blatteigenschaft)
2-blendet die Tabelle aus ‹ Nomenklatur1 ›
3-Tabelle ausblenden ‹ Revisionstabelle1 ›
dann eine .ai-Registrierung
und zeigen Sie schließlich die Hide-Elemente erneut an.

Vielen Dank im Voraus für Ihre Hilfe.
Thierry

2

Hallo

Mehrere Fragen:

  • Ein einzelnes Blatt?
  • Eine Stückliste und eine Revisionstabelle pro Seite?

Das Ausblenden von Elementen ist im Makro nicht sehr kompliziert, aber Sie müssen die Anzahl der zu verbergenden Elemente kennen und wissen, ob eine Verarbeitung auf mehreren Blättern erfolgt oder nicht

1 „Gefällt mir“
3

Hallo
ja, ein einzelnes Blatt ‹ Blatt1 ›
Eine Stückliste ‹ Zeitplan1 ›
und eine einzelne Revisionstabelle ‹ Revisionstabelle1 ›

Vielen Dank
image

5

Hallo

Code unten zum Testen:

Dim swSheet         As SldWorks.Sheet
Dim swApp           As SldWorks.SldWorks
Dim swModel         As SldWorks.ModelDoc2
Dim swModelDocExt   As ModelDocExtension
Dim swDraw          As SldWorks.DrawingDoc
Dim swView          As SldWorks.View
Dim swAnn           As SldWorks.Annotation
Dim boolstatus      As Boolean
Dim sPathName       As String
Dim lErrors         As Long
Dim lWarnings       As Long

Sub main()

Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc
If swModel Is Nothing Then
    MsgBox ("Pas de document ouvert")
    Exit Sub
    Else
        Set swModelDocExt = swModel.Extension
        If swModel.GetType <> 3 Then
            MsgBox ("Il ne s'agît pas d'une mise en plan")
        Else
            Set swDraw = swModel
            Set swSheet = swDraw.GetCurrentSheet
            swSheet.SheetFormatVisible = False ' Masque le fond de plan
            Set swView = swDraw.GetFirstView
            Do While Not Nothing Is swView
                Set swAnn = swView.GetFirstAnnotation3
                Do While Not Nothing Is swAnn
                    If swAnn.GetType = swTableAnnotation Then 'Verifie si c'est un objet de type table (BOM ou révision)
                        swAnn.Visible = swAnnotationHidden ' Cache les tables
                    End If
                Set swAnn = swAnn.GetNext3
                Loop
                Set swView = swView.GetNextView
            Loop
            sPathName = swModel.GetPathName 'Recupere le nom complet du document actif
            sPathName = Left(sPathName, Len(sPathName) - 6) 'Suppression de l'extension
            sPathName = sPathName + "ai" 'Formatage du nom d'enregistrement
            boolstatus = swModelDocExt.SaveAs3(sPathName, swSaveAsCurrentVersion, swSaveAsOptions_Silent, Nothing, Nothing, lErrors, lWarnings)
        End If
        swSheet.SheetFormatVisible = True 'Affiche le fond de plan
        Set swView = swDraw.GetFirstView
            Do While Not Nothing Is swView
                Set swAnn = swView.GetFirstAnnotation3
                Do While Not Nothing Is swAnn
                    If swAnn.GetType = swTableAnnotation Then 'Verifie si c'est un objet de type table (BOM ou révision)
                        swAnn.Visible = swAnnotationVisible ' Affiche les tables
                    End If
                Set swAnn = swAnn.GetNext3
                Loop
                Set swView = swView.GetNextView
            Loop
End If
End Sub

Es wurde nicht berücksichtigt, ob die AI-Datei existiert oder nicht (Hinzufügen möglich)

1 „Gefällt mir“
6

Danke, das ist perfekt!!

1 „Gefällt mir“
7

Hallo

Ich habe ein Thema übersprungen.

Wenn mehrere Blätter, möchte ich nur das 1. Blatt in Ai speichern, derzeit speichert das Makro alle Blätter
Danke für Ihre Hilfe.
Thierry