Macro verbergen basiskaart, stuklijsttabel (geen ballon) en revisietabel

Macro
1

Hallo
Voor een tekening-export alleen met weergaven, ben ik op zoek naar een macro die:
1 - verbergt de basiskaart (verwijder het vinkje bij ' Toon basiskaart ' in de eigenschap van het werkblad)
2-verbergt de tafel ‹ Nomenclatuur1 ›
3-Verberg tabel ‹ Revisietabel1 ›
Dan een .ai registratie
en ten slotte de verbergelementen opnieuw weergeven.

Bij voorbaat dank voor jullie hulp.
Thierry

2

Hallo

Een aantal vragen:

  • Een enkel vel?
  • Eén stuklijst en één revisietabel per pagina?

Het verbergen van elementen is niet erg ingewikkeld in macro's, maar je moet weten hoeveel elementen je wilt verbergen en of een verwerking op meerdere vellen is of niet

1 like
3

Hallo
ja, een enkel blad ‹ Blad1 ›
Eén stuklijst ‹ Schema1 ›
en een enkele revisietabel ‹ Revisietabel1 ›

Bedankt
image

5

Hallo

Onderstaande code om te testen:

Dim swSheet         As SldWorks.Sheet
Dim swApp           As SldWorks.SldWorks
Dim swModel         As SldWorks.ModelDoc2
Dim swModelDocExt   As ModelDocExtension
Dim swDraw          As SldWorks.DrawingDoc
Dim swView          As SldWorks.View
Dim swAnn           As SldWorks.Annotation
Dim boolstatus      As Boolean
Dim sPathName       As String
Dim lErrors         As Long
Dim lWarnings       As Long

Sub main()

Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc
If swModel Is Nothing Then
    MsgBox ("Pas de document ouvert")
    Exit Sub
    Else
        Set swModelDocExt = swModel.Extension
        If swModel.GetType <> 3 Then
            MsgBox ("Il ne s'agît pas d'une mise en plan")
        Else
            Set swDraw = swModel
            Set swSheet = swDraw.GetCurrentSheet
            swSheet.SheetFormatVisible = False ' Masque le fond de plan
            Set swView = swDraw.GetFirstView
            Do While Not Nothing Is swView
                Set swAnn = swView.GetFirstAnnotation3
                Do While Not Nothing Is swAnn
                    If swAnn.GetType = swTableAnnotation Then 'Verifie si c'est un objet de type table (BOM ou révision)
                        swAnn.Visible = swAnnotationHidden ' Cache les tables
                    End If
                Set swAnn = swAnn.GetNext3
                Loop
                Set swView = swView.GetNextView
            Loop
            sPathName = swModel.GetPathName 'Recupere le nom complet du document actif
            sPathName = Left(sPathName, Len(sPathName) - 6) 'Suppression de l'extension
            sPathName = sPathName + "ai" 'Formatage du nom d'enregistrement
            boolstatus = swModelDocExt.SaveAs3(sPathName, swSaveAsCurrentVersion, swSaveAsOptions_Silent, Nothing, Nothing, lErrors, lWarnings)
        End If
        swSheet.SheetFormatVisible = True 'Affiche le fond de plan
        Set swView = swDraw.GetFirstView
            Do While Not Nothing Is swView
                Set swAnn = swView.GetFirstAnnotation3
                Do While Not Nothing Is swAnn
                    If swAnn.GetType = swTableAnnotation Then 'Verifie si c'est un objet de type table (BOM ou révision)
                        swAnn.Visible = swAnnotationVisible ' Affiche les tables
                    End If
                Set swAnn = swAnn.GetNext3
                Loop
                Set swView = swView.GetNextView
            Loop
End If
End Sub

Heeft niet behandeld of het ai-bestand bestaat of niet (mogelijk om toe te voegen)

1 like
6

Bedankt, dat is perfect!!

1 like
7

Hallo

Ik heb een onderwerp overgeslagen.

Als er meerdere vellen zijn, wil ik alleen het 1e vel in Ai opslaan, momenteel slaat de macro alle vellen op
Bedankt voor je hulp.
Thierry